Lua教程

发表于 分类于

官方

https://www.lua.org/

https://www.lua.org/docs.html

下载并编译源代码

Linux

Windows

面向新手的 Windows Lua 编程入门 完全按照这个教程走即可，工作目录修改为 X:\Program\gcc-lua-install，最终结构如图：

image-20260115160213292

创建 Windows Shell 脚本 build.cmd 来驱动构建，内容如下：

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
@echo off
:: ========================
:: file build.cmd
:: ========================
setlocal
:: 您可以根据下载的版本更改以下变量的值
set lua_version=5.5.0

:: 获取当前执行脚本所在的驱动器盘符和目录路径，%~dp0 在非脚本环境下不生效
set work_dir=%~dp0
:: 因为 %~dp0 结尾自带反斜杠，为了提高可读性，移除末尾的反斜杠
set work_dir=%work_dir:~0,-1%

set lua_install_dir=%work_dir%\lua
set compiler_bin_dir=%work_dir%\TDM-GCC-64\bin
set lua_build_dir=%work_dir%\lua-%lua_version%
set path=%compiler_bin_dir%;%path%

cd /D %lua_build_dir%
mingw32-make PLAT=mingw

echo.
echo **** COMPILATION TERMINATED ****
echo.
echo **** BUILDING BINARY DISTRIBUTION ****
echo.

:: 创建一个干净的“二进制”安装
mkdir %lua_install_dir%
mkdir %lua_install_dir%\doc
mkdir %lua_install_dir%\bin
mkdir %lua_install_dir%\include

copy %lua_build_dir%\doc\*.* %lua_install_dir%\doc\*.*
copy %lua_build_dir%\src\*.exe %lua_install_dir%\bin\*.*
copy %lua_build_dir%\src\*.dll %lua_install_dir%\bin\*.*
copy %lua_build_dir%\src\luaconf.h %lua_install_dir%\include\*.*
copy %lua_build_dir%\src\lua.h %lua_install_dir%\include\*.*
copy %lua_build_dir%\src\lualib.h %lua_install_dir%\include\*.*
copy %lua_build_dir%\src\lauxlib.h %lua_install_dir%\include\*.*
copy %lua_build_dir%\src\lua.hpp %lua_install_dir%\include\*.*

echo.
echo **** BINARY DISTRIBUTION BUILT ****
echo.

%lua_install_dir%\bin\lua.exe -e"print [[Hello!]];print[[Simple Lua test successful!!!]]"

echo.

pause